Флеш Уроки

/*
Нам необходимо создать объект BitmapData, чтобы работать с пикселами объекта  Bitmap
Мы хотим, чтобы wallCanvas был прозрачным вначале,
вот почему мы используем значение 0x00ffffff как  параметр
*/
var wallCanvas:BitmapData  = new BitmapData(stage.stageWidth,
stage.stageHeight - 100,
true, 0x00ffffff);

//Создадим объект Bitmap чтобы ссылаться на объект  BitmapData
var bitmap:Bitmap = new Bitmap(wallCanvas);

//Добавим витмап на сцену
addChild (bitmap);

//Мы слушаем событие mouse down на стене
drawingArea.addEventListener (MouseEvent.MOUSE_DOWN, mouseDownHandler);

//Мы слушаем событие  mouse up для всей сцены
stage.addEventListener (MouseEvent.MOUSE_UP, mouseUpHandler);

//Это цвет спрея
var color:uint;

//Это максимальный радиус спрея
var maxRadius:Number;

//Это плотность спрея
var density:Number;

//Это вызывается, когда мышь нажимается на стене
function mouseDownHandler (event:MouseEvent):void {
//Добавляем ENTER_FRAME, чтобы мы могли рисовать в каждом фрейме
addEventListener (Event.ENTER_FRAME, onEnterFrame);
}

//Это вызывается, когда мышь отжимается
function mouseUpHandler (event:MouseEvent):void {
//У нас нет необходимости в  ENTER_FRAME, если мышь отжата (ничего не рисуется)
removeEventListener (Event.ENTER_FRAME, onEnterFrame);
}

//Эта функция отвечает за все рисование
function onEnterFrame (event:Event):void {

//Получим размер из  sizeSlider
maxRadius = sizeSlider.value;

/*
Получим цвет из  myColorPicker.
Мы добавим 0xff000000 к цвету, чтобы сделать пиксел
видимым когда мы рисуем его (мы рисуем пиксел в цикле).
*/
color = myColorPicker.selectedColor + 0xff000000;

//Получим плотность из densitySlider
density = densitySlider.value;

/*
Плотность определяет, сколько циклов мы имеем.
Другими словами, сколько пикселей рисуется в каждом фрейме.
*/
for (var i:int = 0; i < density; i++) {
   
  //Вычисляем рандомный угол
  var angle:Number = Math.random() * Math.PI * 2;
   
  // Вычисляем рандомный радиус для отрисовки пиксела
  var radius:Number = Math.random() * maxRadius;
   
  //Вычисляем координаты по  x и y
  var xPos:Number = mouseX + Math.cos(angle) * radius;
  var yPos:Number = mouseY + Math.sin(angle) * radius;
   
  //Рисуем пиксел.
  wallCanvas.setPixel32 (xPos, yPos, color);
}
}